'''''''''''基本配置开始'''''''''''''''''''''''''''''''''''

  strROSScriptFile = "ROS4.3.txt"    'ROS脚本文件
  strXSConfig = "PcMacList.dat"    '要输出到的迅闪配置精灵所需配置文件，会覆盖掉原文件，请注意备份
  strPrefix = "D6G-"    '计算机名前缀
  strSuffix = ""    '计算机名后缀，如果没有就设为等于双引号""，俗称留空
  intLen = 3    '机号长度，比如长度为3时，一号机为 前缀+001+后缀，即机号短于长度时自动补零补足长度
  strGateway = "192.168.1.1"    '网关
  strSubnetMask = "255.255.255.0"    '子网掩码
  strDNS = "202.189.127.106,221.12.1.228"    '不用说了吧

  '''''''''''基本配置结束'''''''''''''''''''''''''''''''''''
  
  'Code by LZ-MyST QQ:8450919
  Set FSO = WScript.Createobject("Scripting.Filesystemobject")
  If Not FSO.FileExists(strROSScriptFile) Then
    Msgbox("ROS Script File Not Found")
    WScript.Quit
  End If
  Set ReadFile = FSO.OpenTextFile(strROSScriptFile)
  Set WriteFile = FSO.OpenTextFile(strXSConfig,2,True)
  Do Until ReadFile.AtEndOfStream
    strRead = ReadFile.ReadLine
    Set Matches = GetMatche("([0-9]+)\.([0-9]+)\.([0-9]+)\.([0-9]+)",strRead)
    'Msgbox Matches.Count
    If Matches.Count = 1 Then
      Set SubMatche = Matches(0)
      strIP = SubMatche.SubMatches(0) & "." & _
              SubMatche.SubMatches(1) & "." & _
              SubMatche.SubMatches(2) & "." & _
              SubMatche.SubMatches(3)
      strComputerName = strPrefix & String(intLen-Len(SubMatche.SubMatches(3)),"0") & SubMatche.SubMatches(3) & strSuffix
      Set Matches = GetMatche("(.{2}):(.{2}):(.{2}):(.{2}):(.{2}):(.{2})",strRead)
      '如果所读取的行中没有MAC则读取下一行
      '请注意了，要么IP/MAC在同一行，要么IP在第一行，MAC在第二行，不是这样的格式将会出错
      If Matches.Count = 0 Then
        strRead = ReadFile.ReadLine
        Set Matches = GetMatche("(.{2}):(.{2}):(.{2}):(.{2}):(.{2}):(.{2})",strRead)
      End If
      For Each Matche In Matches
        strMac = Replace(Matche.Value,":","")
      Next
      WriteFile.Writeline strMac & "=" & strComputerName & "|" & strIP & "|" & strSubnetMask & "|" & strGateway & "|" & strDNS
    End If
  Loop



'******************************************
'目的：正则表达式
'输入：strPatrn：正则表达式模式
'      strString：要执行正则表达式的字符串
'返回：Match对象
'Code by LZ-MyST QQ:8450919
'******************************************
Function GetMatche(strPatrn, strString)
  Dim RegEx
  Set RegEx = New Regexp
  'RegEx.Global = True
  '如果为True则返回所有符合规则的子字符串(俗称贪婪模式)
  '比如"192.168.1.1",当True时，192.168.1.1/92.168.1.1/2.168.1.1都是符合规则的子字符串
  '默认为False，只返回符合规则的最长的子字符串
  'RegEx.IgnoreCase =True    '是否区分大小写，默认为False，不区分大小写
  RegEx.Pattern = strPatrn
  Set GetMatche = RegEx.Execute(strString)
End Function